Videogioco Dino

joystick_servomotors.ino

// https://nemiatools.com
//https://nemiatools.com
#include <Wire.h> // Includi la libreria di comunicazione I2C
#include <LiquidCrystal_I2C.h> // Includi la libreria LCD I2C

#define buttonPin 2 // Definisci il pin di input del pulsante
LiquidCrystal_I2C lcd(0x27, 16, 2); // Crea l'oggetto display LCD

byte dino1[8] = { // Definisci il primo sprite del dinosauro
  B00111,
  B00101, 
  B00111,
  B00100,
  B01111,
  B11100, 
  B11100, 
  B00100
};

byte dino2[8] = { // Definisci il secondo sprite del dinosauro
  B00111,
  B00101,
  B00111,
  B00100,
  B01111,
  B11100, 
  B11100,
  B10000 
};

byte cactus[8] = { // Definisci lo sprite personalizzato del cactus
  B00100,
  B00100, 
  B10100, 
  B10101,
  B11111, 
  B00100,
  B00100,
  B01110
};

//coordinate del dinosauro
const int dinoX = 4; // Imposta la posizione orizzontale del dinosauro
int dinoY = 1; // Imposta la posizione verticale del dinosauro

//coordinate del cactus
int cactusX = 15; // Imposta la posizione orizzontale del cactus
const int cactusY = 1; // Imposta la posizione verticale del cactus
//millis per il salto 
unsigned long lastJump = 0; // Memorizza l'ora dell'ultimo salto
unsigned long jumpDuration= 600; // Imposta il tempo della durata del salto

//millis per il tempo di gioco
unsigned long startGame = 0; // Memorizza l'ora di inizio del gioco
unsigned long gameTime = 0; // Memorizza il tempo trascorso
int timeX; // Memorizza la posizione del cursore del timer

//stati del pulsante
bool buttonState; // Memorizza lo stato corrente del pulsante
bool oldButtonState = false; // Memorizza lo stato precedente del pulsante


void setup() {
  pinMode(buttonPin, INPUT); // Configura il pulsante come input
  lcd.init();          // Inizializza il display LCD
  lcd.backlight();     // Accende la retroilluminazione LCD
  
  // Salva la memoria dei caratteri personalizzati
  lcd.createChar(0, dino1); // Salva il primo sprite del dinosauro
  lcd.createChar(1, dino2); // Salva il secondo sprite del dinosauro
  lcd.createChar(2, cactus); // Salva lo sprite personalizzato del cactus

  //Menu iniziale
  lcd.setCursor(0, 0); // Imposta il cursore sulla prima riga
  lcd.print("DINO GAME"); // Stampa il testo del titolo del gioco
  lcd.setCursor(0, 1); // Imposta il cursore sulla seconda riga
  lcd.print("by NEMIAtools"); // Stampa il testo del nome dell'autore
  while (true){ // Aspetta finché non viene premuto il pulsante
    if(digitalRead(buttonPin)) break; // Esci quando il pulsante viene premuto
  }
  while(digitalRead(buttonPin)){ // Aspetta finché il pulsante non viene rilasciato
  }
}

void game(){ // Esegui la funzione principale del gioco
  startGame = millis(); // Salva l'ora corrente di inizio
  lastJump = millis() - jumpDuration; // Azzera lo stato del tempo di salto
  oldButtonState = false; // Azzera lo stato precedente del pulsante
  dinoY = 1; // Posiziona il dinosauro a terra
  bool dinoState = true; // Imposta lo stato dell'animazione del dinosauro

  while(true){ // Ripeti il ciclo principale del gioco per sempre
    gameTime = (millis() - startGame) / 10; // Calcola i centesimi di secondo trascorsi
    lcd.clear(); // Cancella il contenuto del display LCD

    buttonState = digitalRead(buttonPin); // Leggi lo stato corrente del pulsante
    if(buttonState && !oldButtonState && millis() - lastJump >= jumpDuration){ // Controlla una richiesta valida di salto
      lastJump = millis(); // Salva il nuovo tempo di salto
    }
    oldButtonState = buttonState; // Aggiorna lo stato precedente del pulsante
    
    if(millis() - lastJump < jumpDuration) dinoY = 0; // Sposta il dinosauro verso l'alto mentre salta
    else dinoY = 1; // Riporta il dinosauro verso il basso
    
    if(gameTime > 99999) gameTime = 99999; // Limita il tempo massimo visualizzato
    timeX = String(gameTime).length(); // Conta la lunghezza delle cifre del timer
    lcd.setCursor(16 - timeX, 0); // Allinea il timer sul lato destro
    lcd.print(gameTime); // Stampa il tempo di gioco corrente
    
    lcd.setCursor(cactusX, cactusY); // Imposta il cursore sul cactus
    lcd.write(byte(2)); // Disegna il carattere personalizzato del cactus
    lcd.setCursor(dinoX, dinoY); // Imposta il cursore sul dinosauro
    if(dinoState) lcd.write(byte(0)); // Disegna il primo frame del dinosauro
    else lcd.write(byte(1)); // Disegna il secondo frame del dinosauro
    
    if((cactusX == dinoX) && (cactusY == dinoY)){ // Controlla la collisione con il cactus
      lcd.setCursor((dinoX + 1), cactusY); // Imposta il cursore accanto al dinosauro
      lcd.write(byte(2)); // Disegna il cactus dopo la collisione
      break; // Esci immediatamente dal ciclo del gioco
    }

    cactusX--; // Muovi il cactus verso sinistra una volta
    if(cactusX < 0) cactusX = 15; // Reimposta il cactus a destra
    dinoState = !dinoState; // Cambia il frame dell'animazione del dinosauro
    
    delay(100); // Aspetta prima del frame successivo
  }
  return; // Ritorna dalla funzione game
}

void gameover(){ // Esegui la schermata di game over
  lcd.setCursor(0, 0); // Imposta il cursore sulla prima riga
  lcd.print("GAME OVER"); // Stampa il testo game over
  lcd.setCursor(1, 1); // Imposta il cursore sulla seconda riga

  while(digitalRead(buttonPin)){ // Aspetta il rilascio del pulsante
  }
  while(!digitalRead(buttonPin)){ // Aspetta la pressione del pulsante
  }
  while(digitalRead(buttonPin)){ // Aspetta il rilascio del pulsante
  }
  return; // Ritorna dalla funzione gameover
}

void loop() {
  cactusX = 15; // Reimposta la posizione iniziale del cactus
  lcd.clear(); // Cancella l'LCD prima del gioco
  game(); // Avvia la funzione principale del gioco
  gameover(); // Mostra la schermata di game over
}