How to Build an Arduino NTC Thermistor Thermometer with LCD

// https://nemiatools.com
#include <Wire.h> // Include I2C communication library
#include <LiquidCrystal_I2C.h> // Include LCD I2C library
#include <math.h> // Include logarithm function

LiquidCrystal_I2C lcd_1(0x27, 16, 2); // LCD object

#define THERMISTOR_PIN A0 // Thermistor signal pin
const float PULLUP_RESISTOR = 10000.0; // 10k pull-up resistor
const float NOMINAL_RESISTANCE = 10000.0; // NTC resistance at 25°C
const float NOMINAL_TEMPERATURE_K = 25.0 + 273.15; // 25°C in Kelvin
const float BETA_COEFFICIENT = 3950.0; // NTC 3950 beta value

byte degree_symbol[8] = { // Degree symbol
  B00110, // Row 1
  B01001, // Row 2
  B01001, // Row 3
  B00110, // Row 4
  B00000, // Row 5
  B00000, // Row 6
  B00000, // Row 7
  B00000  // Row 8
};

float readTemperatureC() { // Read thermistor temperature
  float adcValue = analogRead(THERMISTOR_PIN); // Read analog divider value

  if (adcValue <= 0) adcValue = 1; // Avoid division by zero
  if (adcValue >= 1023) adcValue = 1022; // Avoid division by zero

  float thermistorResistance = PULLUP_RESISTOR * adcValue / (1023.0 - adcValue); // Calculate NTC resistance

  float temperatureK = 1.0 / ( // Convert resistance to Kelvin
    (1.0 / NOMINAL_TEMPERATURE_K) +
    (1.0 / BETA_COEFFICIENT) * log(thermistorResistance / NOMINAL_RESISTANCE)
  );

  return temperatureK - 273.15; // Return Celsius temperature
}

void setup()
{
  lcd_1.init(); // Initialize LCD
  pinMode(THERMISTOR_PIN, INPUT); // Thermistor divider input

  lcd_1.backlight(); // Enable backlight
  lcd_1.createChar(0, degree_symbol); // Create degree symbol
  lcd_1.setCursor(3, 0); // First line
  lcd_1.print("TERMOMETER"); // Show title
  lcd_1.setCursor(2, 1); // Second line
  lcd_1.print("by Nemiatools"); // Show author
  delay(3000); // 3 seconds for the home screen
  lcd_1.clear(); // Clear display
  lcd_1.setCursor(0, 0); // First line
  lcd_1.print("Temperature:"); // Static text
  lcd_1.setCursor(10, 1); // Degree symbol position
  lcd_1.write(byte(0)); // Print degree symbol
  lcd_1.setCursor(11, 1); // Unit position
  lcd_1.print("C"); // Celsius unit
}

void loop()
{
  lcd_1.setCursor(3, 1); // Temperature value position
  lcd_1.print("      "); // Clear old value
  lcd_1.setCursor(3, 1); // Return to value position
  lcd_1.print(readTemperatureC(), 1); // Print temperature with one decimal
  delay(500); // Update twice per second
}